forked from AngusJohnson/Image32
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathImg32.SVG.PathDesign.pas
1285 lines (1156 loc) · 40.5 KB
/
Img32.SVG.PathDesign.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
unit Img32.SVG.PathDesign;
(*******************************************************************************
* Author : Angus Johnson *
* Version : 4.2 *
* Date : 30 May 2022 *
* Website : http://www.angusj.com *
* Copyright : Angus Johnson 2019-2022 *
* *
* Purpose : Supports designing SVG paths *
* *
* License : Use, modification & distribution is subject to *
* Boost Software License Ver 1 *
* http://www.boost.org/LICENSE_1_0.txt *
*******************************************************************************)
interface
{$I Img32.inc}
uses
SysUtils, Classes, Types, Math,
Img32, Img32.SVG.Core, Img32.Svg.Path, Img32.Vector, Img32.Layers;
type
TSegPos = (spFirst, spMiddle, spLast);
TSubPathLayer = class;
TSvgPathLayer = class;
TPathSegLayer = class(TVectorLayer32)
private
fOwner : TSvgPathLayer;
fFocused : Boolean;
fRotAngle : double;
fSeg : TSvgPathSeg;
protected
function GetPrevSegLayer: TPathSegLayer;
function GetNextSegLayer: TPathSegLayer;
function GetDesignerLayer(btnLayer: TLayer32): TLayer32;
procedure DrawDesigner(designer: TLayer32); virtual;
procedure SetFocus(value: Boolean);
procedure SetBtnCtrlPts(const pts: TPathD); virtual;
procedure BtnMoveCheck(const pos: TPointD); virtual;
property Owner: TSvgPathLayer read fOwner;
public
constructor Create(parent: TLayer32 = nil; const name: string = ''); override;
procedure Init(seg: TSvgPathSeg); virtual;
function CreateBtnGroup: TButtonGroupLayer32; virtual;
procedure UpdateBtnGroup(movedBtn: TLayer32); virtual;
function CreateRotateBtnGroup(target: TPathSegLayer;
startAngle: double = 0; angleOffset: double = 0): TRotatingGroupLayer32; virtual;
procedure UpdateRotateBtnGroup(movedBtn: TLayer32); virtual;
function TestUpdateBtnGroup(movedBtn: TLayer32;
var dx, dy: integer): Boolean; virtual;
procedure DrawPath;
property Focused: Boolean read fFocused write SetFocus;
property Seg: TSvgPathSeg read fSeg;
end;
TSvgASegLayer = class(TPathSegLayer)
private
fRectMargin : integer;
fRotateDistance : double;
procedure OffsetHorzBtn(btn: TLayer32);
procedure OffsetVertBtn(btn: TLayer32);
function GetPointFromHorzBtn(btn: TLayer32): TPointD;
function GetPointFromVertBtn(btn: TLayer32): TPointD;
protected
procedure DrawDesigner(designer: TLayer32); override;
public
constructor Create(parent: TLayer32 = nil; const name: string = ''); override;
procedure Init(seg: TSvgPathSeg); override;
function CreateBtnGroup: TButtonGroupLayer32; override;
function TestUpdateBtnGroup(movedBtn: TLayer32;
var dx, dy: integer): Boolean; override; //todo - redo this with absolute points
procedure UpdateBtnGroup(movedBtn: TLayer32); override;
function CreateRotateBtnGroup(target: TPathSegLayer;
startAngle: double = 0; angleOffset: double = 0): TRotatingGroupLayer32; override;
procedure UpdateRotateBtnGroup(movedBtn: TLayer32); override;
procedure ReverseArcDirection;
//RectMargin: offset for rec ctrl buttons (horz. & vert.)
//so they stay out of the way of the arc button
property RectMargin: integer read fRectMargin write fRectMargin;
end;
TSvgCSegLayer = class(TPathSegLayer)
protected
procedure DrawDesigner(designer: TLayer32); override;
public
function CreateBtnGroup: TButtonGroupLayer32; override;
end;
TSvgHSegLayer = class(TPathSegLayer)
public
function TestUpdateBtnGroup(movedBtn: TLayer32;
var dx, dy: integer): Boolean; override;
end;
TSvgLSegLayer = class(TPathSegLayer)
end;
TSvgQSegLayer = class(TPathSegLayer)
public
function CreateBtnGroup: TButtonGroupLayer32; override;
procedure DrawDesigner(designer: TLayer32); override;
end;
TSvgSSegLayer = class(TPathSegLayer)
protected
procedure BtnMoveCheck(const pos: TPointD); override;
public
function CreateBtnGroup: TButtonGroupLayer32; override;
procedure DrawDesigner(designer: TLayer32); override;
end;
TSvgTSegLayer = class(TPathSegLayer)
protected
procedure BtnMoveCheck(const pos: TPointD); override;
end;
TSvgVSegLayer = class(TPathSegLayer)
public
function TestUpdateBtnGroup(movedBtn: TLayer32;
var dx, dy: integer): Boolean; override; //todo - redo this with absolute points
end;
TSvgZSegLayer = class(TPathSegLayer)
protected
procedure BtnMoveCheck(const pos: TPointD); override;
public
function CreateBtnGroup: TButtonGroupLayer32; override;
function TestUpdateBtnGroup(movedBtn: TLayer32;
var moveDx, moveDy: integer): Boolean; override;
procedure UpdateBtnGroup(movedBtn: TLayer32); override;
function CreateRotateBtnGroup(target: TPathSegLayer;
startAngle: double = 0; angleOffset: double = 0): TRotatingGroupLayer32; override;
procedure UpdateRotateBtnGroup(movedBtn: TLayer32); override;
end;
TSubPathLayer = class(TGroupLayer32)
private
fOwner : TSvgPathLayer;
fSubPath : TSvgSubPath;
function GetSegLayer(index: integer): TPathSegLayer;
protected
property Owner : TSvgPathLayer read fOwner;
public
procedure Init(subPath: TSvgSubPath); virtual;
procedure Offset(dx, dy: double); override;
function GetLastSegLayer: TPathSegLayer;
function GetStringDef(getAsRelative: Boolean; decimalPrec: integer): string;
property SubPath: TSvgSubPath read fSubPath;
property SegLayer[index: integer]: TPathSegLayer read GetSegLayer;
end;
TSvgPathLayer = class(TGroupLayer32)
private
fStrokeColor : TColor32;
fStrokeColor2 : TColor32;
fstrokeWidth : double;
fRelativeStr : Boolean;
fSvgPath : TSvgPath;
function GetMargin: integer;
procedure SetStrokeWidth(width: double);
function GetSubPathLayer(index: integer): TSubPathLayer;
protected
property StrokeColor : TColor32 read fStrokeColor;
property StrokeColor2 : TColor32 read fStrokeColor2;
public
constructor Create(parent: TLayer32 = nil; const name: string = ''); override;
destructor Destroy; override;
procedure LoadPath(const dpath: string; const destRect: TRect; scale: double = 0);
procedure LoadPathsFromFile(const filename: string;
const destRect: TRect; scale: double = 0);
property StrokeWidth : double read fstrokeWidth write SetStrokeWidth;
property SvgPath: TSvgPath read fSvgPath;
property SvgSubPath[index: integer]: TSubPathLayer read GetSubPathLayer;
property Margin : integer read GetMargin;
end;
implementation
uses
Img32.Extra, Img32.Draw, Img32.SVG.Reader;
resourcestring
rsErrorCreatingButtonGroup =
'Error: only the last segment in an SVG path can be edited.';
rsErrorArc = 'Error: Invalid Arc segment.';
const
controlBtnColor : TColor32 = $FFFFBB00;
arcRectBtnColor : TColor32 = clGreen32;
rotatePivotColor : TColor32 = clLime32;
rotateBtnColor : TColor32 = clGreen32;
//------------------------------------------------------------------------------
// TPathSegLayer
//------------------------------------------------------------------------------
constructor TPathSegLayer.Create(parent: TLayer32; const name: string);
begin
inherited Create(parent, name);
fOwner := Parent.Parent as TSvgPathLayer;
OuterMargin := Max(fOwner.Margin, Ceil(DefaultButtonSize /2));
end;
//------------------------------------------------------------------------------
procedure TPathSegLayer.Init(seg: TSvgPathSeg);
begin
fSeg := seg;
Paths := Img32.Vector.Paths(fSeg.FlatPath);
DrawPath;
end;
//------------------------------------------------------------------------------
procedure TPathSegLayer.DrawPath;
var
c: TColor32;
p: TPathD;
begin
if not Assigned(Paths) or not Assigned(Paths[0]) then Exit;
Image.Clear; //Image.Clear($10FF0000); //debugging :)
if Focused then c := Owner.fStrokeColor2 else c := Owner.fStrokeColor;
p := OffsetPath(Paths[0], -Left+OuterMargin, -Top+OuterMargin);
DrawLine(Image, p, Owner.StrokeWidth, c, esRound);
//UpdateHitTestMaskFromImage;
//draw a wider stroke to define the HT region
HitTest.htImage.SetSize(Image.Width, Image.Height);
DrawLine(HitTest.htImage, p, Owner.StrokeWidth*2, clBlack32, esRound);
end;
//------------------------------------------------------------------------------
procedure TPathSegLayer.SetBtnCtrlPts(const pts: TPathD);
begin
fSeg.CtrlPts := pts;
Paths := Img32.Vector.Paths(fSeg.FlatPath);
end;
//------------------------------------------------------------------------------
function TPathSegLayer.GetPrevSegLayer: TPathSegLayer;
var
layer: TLayer32;
begin
layer := PrevLayerInGroup;
if Assigned(layer) and (layer is TPathSegLayer) then
Result := TPathSegLayer(layer) else
Result := nil;
end;
//------------------------------------------------------------------------------
function TPathSegLayer.GetNextSegLayer: TPathSegLayer;
var
layer: TLayer32;
begin
layer := NextLayerInGroup;
if Assigned(layer) and (layer is TPathSegLayer) then
Result := TPathSegLayer(layer) else
Result := nil;
end;
//------------------------------------------------------------------------------
function TPathSegLayer.GetDesignerLayer(btnLayer: TLayer32): TLayer32;
begin
if Assigned(btnLayer) and
(btnLayer.Parent is TButtonGroupLayer32) and
(btnLayer.Parent[0] is TLayer32) then
Result := TLayer32(btnLayer.Parent[0])
else
Result := nil;
end;
//------------------------------------------------------------------------------
procedure TPathSegLayer.DrawDesigner(designer: TLayer32);
begin
end;
//------------------------------------------------------------------------------
procedure TPathSegLayer.SetFocus(value: Boolean);
begin
if fFocused = value then Exit;
fFocused := value;
DrawPath;
end;
//------------------------------------------------------------------------------
function TPathSegLayer.CreateBtnGroup: TButtonGroupLayer32;
var
designer: TLayer32;
begin
Result := CreateButtonGroup(Root,
fSeg.ctrlPts, bsRound, DefaultButtonSize, clRed32);
//insert the designer layer **below** the button layers
designer := Result.InsertChild(TLayer32, 0) as TLayer32;
DrawDesigner(designer);
end;
//------------------------------------------------------------------------------
function TPathSegLayer.TestUpdateBtnGroup(movedBtn: TLayer32;
var dx, dy: integer): Boolean;
begin
Result := (movedBtn is TButtonDesignerLayer32) or
not TButtonDesignerLayer32(movedBtn).Enabled;
end;
//------------------------------------------------------------------------------
procedure TPathSegLayer.BtnMoveCheck(const pos: TPointD);
var
segLayer : TPathSegLayer;
dx, dy : integer;
begin
if PointsEqual(pos, fSeg.FirstPt) then Exit;
dx := Round(pos.X - fSeg.FirstPt.X);
dy := Round(pos.Y - fSeg.FirstPt.Y);
fSeg.Offset(dx, dy);
Offset(dx, dy);
segLayer := GetNextSegLayer;
if Assigned(segLayer) then
segLayer.BtnMoveCheck(fSeg.CtrlPts[High(fSeg.CtrlPts)]);
end;
//------------------------------------------------------------------------------
procedure TPathSegLayer.UpdateBtnGroup(movedBtn: TLayer32);
var
i : integer;
pts : TPathD;
designer : TLayer32;
segLayer : TPathSegLayer;
begin
designer := GetDesignerLayer(movedBtn);
if not assigned(designer) then Exit;
i := TButtonDesignerLayer32(movedBtn).BtnIdx;
pts := fSeg.ctrlPts;
if i >= Length(pts) then Exit;
pts[i] := movedBtn.MidPoint;
SetBtnCtrlPts(pts);
DrawPath;
DrawDesigner(designer);
//move the following segments
segLayer := GetNextSegLayer;
if Assigned(segLayer) then
segLayer.BtnMoveCheck(pts[High(pts)]);
end;
//------------------------------------------------------------------------------
function TPathSegLayer.CreateRotateBtnGroup(target: TPathSegLayer;
startAngle: double; angleOffset: double): TRotatingGroupLayer32;
begin
// if (GetNextSegLayer <> nil) then
// Raise Exception.Create(rsErrorCreatingButtonGroup);
//get control points stripped of local coord reference
//fRotAngle := 0;
Result := CreateRotatingButtonGroup(target, fSeg.FirstPt, DefaultButtonSize,
clWhite32, rotateBtnColor, startAngle, angleOffset);
end;
//------------------------------------------------------------------------------
procedure TPathSegLayer.UpdateRotateBtnGroup(movedBtn: TLayer32);
var
a: double;
segLayer : TPathSegLayer;
pts: TPathD;
begin
if not (movedBtn.Parent is TRotatingGroupLayer32) then Exit;
a := UpdateRotatingButtonGroup(movedBtn);
pts := RotatePath(fSeg.ctrlPts, fSeg.FirstPt, a - fRotAngle);
fSeg.CtrlPts := pts;
fRotAngle := a;
Paths := Img32.Vector.Paths(fSeg.FlatPath);
DrawPath;
//move the following segments
segLayer := GetNextSegLayer;
if Assigned(segLayer) then
with Self.fSeg do
segLayer.BtnMoveCheck(ctrlPts[High(ctrlPts)]);
end;
//------------------------------------------------------------------------------
// TSvgASegLayer
//------------------------------------------------------------------------------
constructor TSvgASegLayer.Create(parent: TLayer32 = nil; const name: string = '');
begin
inherited Create(parent, name);
fRectMargin := 20;
end;
//------------------------------------------------------------------------------
procedure TSvgASegLayer.Init(seg: TSvgPathSeg);
begin
fSeg := seg;
Paths := Img32.Vector.Paths(fSeg.FlatPath);
DrawPath;
end;
//------------------------------------------------------------------------------
procedure TSvgASegLayer.ReverseArcDirection;
begin
TSvgASegment(fSeg).ReverseArc;
Paths := Img32.Vector.Paths(fSeg.FlatPath);
DrawPath;
Invalidate;
end;
//------------------------------------------------------------------------------
procedure TSvgASegLayer.OffsetHorzBtn(btn: TLayer32);
var
pt: TPointD;
begin
pt := btn.MidPoint;
with TSvgASegment(fSeg), arcInfo do
begin
if rectAngle <> 0 then RotatePoint(pt, rec.MidPoint, -rectAngle);
if IsLeftCtrl then
pt.X := pt.X - fRectMargin else
pt.X := pt.X + fRectMargin;
if rectAngle <> 0 then RotatePoint(pt, rec.MidPoint, rectAngle);
end;
btn.PositionCenteredAt(pt);
end;
//------------------------------------------------------------------------------
procedure TSvgASegLayer.OffsetVertBtn(btn: TLayer32);
var
pt: TPointD;
begin
pt := btn.MidPoint;
with TSvgASegment(fSeg), arcInfo do
begin
if rectAngle <> 0 then RotatePoint(pt, rec.MidPoint, -rectAngle);
if IsTopCtrl then
pt.Y := pt.Y - fRectMargin else
pt.Y := pt.Y + fRectMargin;
if rectAngle <> 0 then RotatePoint(pt, rec.MidPoint, rectAngle);
end;
btn.PositionCenteredAt(pt);
end;
//------------------------------------------------------------------------------
function TSvgASegLayer.GetPointFromHorzBtn(btn: TLayer32): TPointD;
begin
Result := btn.MidPoint;
with TSvgASegment(fSeg), arcInfo do
begin
if rectAngle <> 0 then RotatePoint(Result, rec.MidPoint, -rectAngle);
if IsLeftCtrl then
Result.X := Result.X + fRectMargin else
Result.X := Result.X - fRectMargin;
if rectAngle <> 0 then RotatePoint(Result, rec.MidPoint, rectAngle);
end;
end;
//------------------------------------------------------------------------------
function TSvgASegLayer.GetPointFromVertBtn(btn: TLayer32): TPointD;
begin
Result := btn.MidPoint;
with TSvgASegment(fSeg), arcInfo do
begin
if rectAngle <> 0 then RotatePoint(Result, rec.MidPoint, -rectAngle);
if IsTopCtrl then
Result.Y := Result.Y + fRectMargin else
Result.Y := Result.Y - fRectMargin;
if rectAngle <> 0 then RotatePoint(Result, rec.MidPoint, rectAngle);
end;
end;
//------------------------------------------------------------------------------
function TSvgASegLayer.CreateBtnGroup: TButtonGroupLayer32;
var
i: integer;
designer: TLayer32;
begin
Result := CreateButtonGroup(Root, fSeg.ctrlPts,
bsRound, DefaultButtonSize, clRed32);
Result[0].Visible := false; //startpos button
OffsetHorzBtn(Result[1]); //left Rec
OffsetVertBtn(Result[3]); //top Rec
for i := 5 to Result.ChildCount -1 do
Result[i].Visible := false; //hide rotation & sweep button
for i := 1 to 3 do
with TButtonDesignerLayer32(Result[i]) do //rect horz
begin
Color := arcRectBtnColor;
Enabled := true;
Draw;
end;
//insert the designer layer below the button layers (ie level 0)
designer := Result.InsertChild(TLayer32, 0) as TLayer32;
DrawDesigner(designer);
end;
//------------------------------------------------------------------------------
function TSvgASegLayer.TestUpdateBtnGroup(movedBtn: TLayer32;
var dx, dy: integer): Boolean;
var
a: double;
r: TRectD;
pt, mp: TPointD;
begin
Result := inherited TestUpdateBtnGroup(movedBtn, dx, dy);
if not Result then Exit;
with TSvgASegment(fSeg), arcInfo do
begin
r := rec;
mp := r.MidPoint;
pt := PointD(movedBtn.MidPoint.X + dx, movedBtn.MidPoint.Y + dy);
if movedBtn.Parent is TRotatingGroupLayer32 then
begin
a := GetAngle(startPos, pt);
pt := GetPointAtAngleAndDist(startPos, a, fRotateDistance);
dx := Round(pt.X - movedBtn.MidPoint.X);
dy := Round(pt.Y - movedBtn.MidPoint.Y);
Exit;
end;
img32.Vector.RotatePoint(pt, mp, -rectAngle);
case TButtonDesignerLayer32(movedBtn).BtnIdx of
1: pt.Y := mp.Y; //rect horz
2: //rect midpoint
begin
Result := true;
Exit;
end;
3: pt.X := mp.X; //rect top
4: //end point
begin
a := GetEllipticalAngleFromPoint(r, pt);
pt := GetPtOnEllipseFromAngle(r, a);
end;
else
begin
Result := false;
Exit;
end;
end;
img32.Vector.RotatePoint(pt, mp, rectAngle);
end;
dx := Round(pt.X - movedBtn.MidPoint.X);
dy := Round(pt.Y - movedBtn.MidPoint.Y);
end;
//------------------------------------------------------------------------------
function FlipAngleHorizontally(angle: double): double;
begin
Result := angle180 - angle;
NormalizeAngle(Result);
end;
//------------------------------------------------------------------------------
function FlipAngleVertically(angle: double): double;
begin
NormalizeAngle(angle);
Result := -angle;
end;
//------------------------------------------------------------------------------
procedure TSvgASegLayer.UpdateBtnGroup(movedBtn: TLayer32);
var
sa,ea, a : double;
dx,dy : double;
mp, sp : TPointD;
designer : TLayer32;
segLayer : TPathSegLayer;
ai : TArcInfo;
begin
designer := GetDesignerLayer(movedBtn);
if not Assigned(designer) then Exit;
with TSvgASegment(fSeg) do
begin
ai := ArcInfo;
case TButtonDesignerLayer32(movedBtn).BtnIdx of
1: //rect horz
begin
//save the start point before resizing rect
//then after resizing, realign the rect so
//the start point doesn't change
sa := GetStartAngle;
ea := GetEndAngle;
//a = button distance adjustment
//ie how much more the rec edge should move to keep it
//aligned with the move button (avoids overshoot & undershoot)
a := 1-Sqrt(Abs(cos(sa)));
mp := GetPointFromHorzBtn(movedBtn);
img32.Vector.RotatePoint(mp, ai.rec.MidPoint, - ai.rectAngle);
if IsLeftCtrl then
begin
dx := mp.X - ai.rec.Left;
ai.rec.Left := ai.rec.Left + dx + a*dx;
end else
begin
dx := mp.X - ai.rec.Right;
ai.rec.Right := ai.rec.Right + dx + a*dx;
end;
if ai.rec.Normalize then
begin
sa := FlipAngleHorizontally(sa);
ea := FlipAngleHorizontally(ea);
ReverseArc;
end;
sp := GetPtOnRotatedEllipseFromAngle(ai.rec, ai.rectAngle, sa);
ai.endPos := GetPtOnRotatedEllipseFromAngle(ai.rec, ai.rectAngle, ea);
dx := ai.startPos.X - sp.X; dy := ai.startPos.Y - sp.Y;
OffsetRect(ai.rec, dx, dy);
ai.endPos := OffsetPoint(ai.endPos, dx, dy);
ArcInfo := ai;
Paths := Img32.Vector.Paths(fSeg.FlatPath);
DrawPath;
DrawDesigner(designer);
movedBtn.PositionCenteredAt(ctrlPts[1]);
OffsetHorzBtn(movedBtn);
movedBtn.Parent[3].PositionCenteredAt(ctrlPts[2]);
movedBtn.Parent[4].PositionCenteredAt(ctrlPts[3]);
OffsetVertBtn(movedBtn.Parent[4]);
movedBtn.Parent[5].PositionCenteredAt(ai.endPos);
end;
2: //rect midpoint
begin
mp := movedBtn.MidPoint;
dx := mp.X - ai.rec.MidPoint.X;
dy := mp.Y - ai.rec.MidPoint.Y;
OffsetRect(ai.rec, dx, dy);
ai.endPos := OffsetPoint(ai.endPos, dx, dy);
sa := GetRotatedEllipticalAngleFromPoint(ai.rec,
ai.rectAngle, ai.startPos);
sp := GetPtOnRotatedEllipseFromAngle(ai.rec, ai.rectAngle, sa);
dx := (ai.startpos.X - sp.X); dy:= (ai.startpos.Y - sp.Y);
OffsetRect(ai.rec, dx, dy);
ai.endPos := OffsetPoint(ai.endPos, dx, dy);
ArcInfo := ai;
Paths := Img32.Vector.Paths(fSeg.FlatPath);
DrawPath;
DrawDesigner(designer);
movedBtn.Parent[2].PositionCenteredAt(ctrlPts[1]);
OffsetHorzBtn(movedBtn.Parent[2]);
movedBtn.Parent[3].PositionCenteredAt(ctrlPts[2]);
movedBtn.Parent[4].PositionCenteredAt(ctrlPts[3]);
OffsetVertBtn(movedBtn.Parent[4]);
movedBtn.Parent[5].PositionCenteredAt(ai.endPos);
end;
3: //rect vert
begin
//save the start point before resizing rect
//then after resizing, realign the rect so
//the start point doesn't change
sa := GetStartAngle;
ea := GetEndAngle;
a := 1-Sqrt(Abs(sin(sa))); //button distance adjustment
mp := movedBtn.MidPoint;
mp := GetPointFromVertBtn(movedBtn);
img32.Vector.RotatePoint(mp, ai.rec.MidPoint, - ai.rectAngle);
if IsTopCtrl then
begin
dy := mp.Y - ai.rec.Top;
ai.rec.Top := ai.rec.Top + dy + a*dy;
end else
begin
dy := mp.Y - ai.rec.Bottom;
ai.rec.Bottom := ai.rec.Bottom + dy + a*dy;
end;
if ai.rec.Normalize then
begin
sa := FlipAngleVertically(sa);
ea := FlipAngleVertically(ea);
ReverseArc;
end;
sp := GetPtOnRotatedEllipseFromAngle(ai.rec, ai.rectAngle, sa);
dx := (ai.startpos.X - sp.X); dy:= (ai.startpos.Y - sp.Y);
OffsetRect(ai.rec, dx, dy);
ai.endPos := GetPtOnRotatedEllipseFromAngle(ai.rec, ai.rectAngle, ea);
ArcInfo := ai;
Paths := Img32.Vector.Paths(fSeg.FlatPath);
DrawPath;
DrawDesigner(designer);
movedBtn.Parent[2].PositionCenteredAt(ctrlPts[1]);
OffsetHorzBtn(movedBtn.Parent[2]);
movedBtn.Parent[3].PositionCenteredAt(ctrlPts[2]);
movedBtn.PositionCenteredAt(ctrlPts[3]);
OffsetVertBtn(movedBtn);
movedBtn.Parent[5].PositionCenteredAt(ai.endPos);
end;
4:
begin
mp := movedBtn.MidPoint;
ai.endPos := GetClosestPtOnRotatedEllipse(ai.rec, ai.rectAngle, mp);
ArcInfo := ai;
Paths := Img32.Vector.Paths(fSeg.FlatPath);
DrawPath;
end;
end; //end case
end; //end with
//move the following segments
segLayer := GetNextSegLayer;
if Assigned(segLayer) then
with TSvgASegment(fSeg).arcInfo do
segLayer.BtnMoveCheck(endPos);
end;
//------------------------------------------------------------------------------
function TSvgASegLayer.CreateRotateBtnGroup(target: TPathSegLayer;
startAngle: double; angleOffset: double): TRotatingGroupLayer32;
var
a: double;
begin
with TSvgASegment(fSeg).arcInfo do
begin
a := GetAngle(startPos, rec.MidPoint) - rectAngle;
Result := inherited CreateRotateBtnGroup(target, rectAngle, a);
Result.AngleButton.PositionCenteredAt(rec.MidPoint);
end;
UpdateRotateBtnGroup(Result.AngleButton);
fRotateDistance := Result.DistBetweenButtons;
end;
//------------------------------------------------------------------------------
procedure TSvgASegLayer.UpdateRotateBtnGroup(movedBtn: TLayer32);
var
a, sa, ea, dx, dy: double;
ai: TArcInfo;
sp: TPointD;
segLayer : TPathSegLayer;
begin
if not (movedBtn.Parent is TRotatingGroupLayer32) then Exit;
a := UpdateRotatingButtonGroup(movedBtn);
if a = 0 then Exit;
with TSvgASegment(fSeg) do
begin
ai := ArcInfo;
//save the start angle before rotating rect
//then after rotating, realign the rect so
//the start point doesn't change
sa := GetStartAngle;
ea := GetEndAngle;
ai.rectAngle := a;
sp := GetPtOnRotatedEllipseFromAngle(ai.rec, ai.rectAngle, sa);
dx := sp.X - ai.startPos.X; dy := sp.Y - ai.startPos.Y;
OffsetRect(ai.rec, -dx, -dy);
ai.endPos := GetPtOnRotatedEllipseFromAngle(ai.rec, ai.rectAngle, ea);
ArcInfo := ai;
Paths := Img32.Vector.Paths(fSeg.FlatPath);
DrawPath;
end;
Invalidate;
//move the following segments
segLayer := GetNextSegLayer;
if Assigned(segLayer) then
with Self.fSeg do
segLayer.BtnMoveCheck(ctrlPts[High(ctrlPts)]);
end;
//------------------------------------------------------------------------------
procedure TSvgASegLayer.DrawDesigner(designer: TLayer32);
var
j: integer;
r,r2: TRectD;
p, p2: TPathD;
dashes: TArrayOfInteger;
begin
j := Ceil(Owner.StrokeWidth);
with TSvgASegment(fSeg).arcInfo do
begin
r := rec;
p := Ellipse(r);
if rectAngle <> 0 then
p := RotatePath(p, r.MidPoint, rectAngle);
r := Img32.Vector.GetBoundsD(p);
p2 := OffsetPath(p, startPos.X - r.MidPoint.X, startPos.Y - r.MidPoint.Y);
r2 := Img32.Vector.GetBoundsD(p2);
r := UnionRect(r, r2);
InflateRect(r, dpiAware1, dpiAware1); //ie pen width
designer.SetInnerBounds(r);
p := OffsetPath(p, -designer.Left, -designer.Top);
SetLength(dashes, 2);
dashes[0] := j; dashes[1] := j;
DrawDashedLine(designer.Image, p, dashes,
nil, dpiAware1, clMaroon32, esPolygon);
p2 := OffsetPath(p2, -designer.Left, -designer.Top);
DrawDashedLine(designer.Image, p2, dashes,
nil, dpiAware1, clSilver32, esPolygon);
end;
end;
//------------------------------------------------------------------------------
// TSvgCSegLayer
//------------------------------------------------------------------------------
function TSvgCSegLayer.CreateBtnGroup: TButtonGroupLayer32;
var
i: integer;
begin
Result := inherited CreateBtnGroup;
//NB: THE FIRST LAYER IN THIS GROUP IS THE DESIGNER LAYER
for i := 1 to Result.ChildCount div 3 do
begin
with TButtonDesignerLayer32(Result[i*3-2]) do
begin
Color := controlBtnColor;
Draw;
end;
with TButtonDesignerLayer32(Result[i*3-1]) do
begin
Color := controlBtnColor;
Draw;
//make sure 'control' buttons are on top of adjacent 'end' buttons
//move every second ctrl button on top of the following button
Move(Result, i*3);
end;
end;
end;
//------------------------------------------------------------------------------
procedure TSvgCSegLayer.DrawDesigner(designer: TLayer32);
var
i,j: integer;
pt: TPointD;
p: TPathD;
dashes: TArrayOfInteger;
begin
j := Ceil(Owner.StrokeWidth);
SetLength(dashes, 2);
dashes[0] := j; dashes[1] := j;
SetLength(p, 2);
with fSeg do
begin
designer.SetInnerBounds(GetCtrlBounds);
pt := FirstPt;
for i := 0 to Length(ctrlPts) div 3 -1 do
begin
p[0] := pt;
p[1] := ctrlPts[i*3];
p := OffsetPath(p, -designer.Left, -designer.Top);
DrawDashedLine(designer.Image, p, dashes,
nil, Self.Owner.StrokeWidth/2, clRed32, esRound);
pt := ctrlPts[i*3+2];
p[0] := ctrlPts[i*3+1];
p[1] := pt;
p := OffsetPath(p, -designer.Left, -designer.Top);
DrawDashedLine(designer.Image, p, dashes,
nil, Self.Owner.StrokeWidth/2, clRed32, esRound);
end;
end;
end;
//------------------------------------------------------------------------------
// TSvgHSegLayer
//------------------------------------------------------------------------------
function TSvgHSegLayer.TestUpdateBtnGroup(movedBtn: TLayer32;
var dx, dy: integer): Boolean;
begin
Result := inherited TestUpdateBtnGroup(movedBtn, dx, dy) and
not (movedBtn.Parent is TRotatingGroupLayer32);
if not Result then Exit;
dy := 0;
end;
//------------------------------------------------------------------------------
function TSvgQSegLayer.CreateBtnGroup: TButtonGroupLayer32;
var
i: integer;
begin
Result := inherited CreateBtnGroup;
//NB: THE FIRST LAYER IN THIS GROUP IS THE DESIGNER LAYER
//and control buttons need to be on top of adjacent 'end' buttons
for i := 1 to Result.ChildCount div 2 do
with TButtonDesignerLayer32(Result[i*2-1]) do
begin
Color := controlBtnColor;
Draw;
Move(Result, i*2);
end;
end;
//------------------------------------------------------------------------------
procedure TSvgQSegLayer.DrawDesigner(designer: TLayer32);
var
i,j: integer;
p: TPathD;
pt: TPointD;
dashes: TArrayOfInteger;
begin
j := Ceil(Owner.StrokeWidth);
SetLength(dashes, 2);
dashes[0] := j; dashes[1] := j;
SetLength(p, 2);
with fSeg do
begin
designer.SetInnerBounds(GetCtrlBounds);
pt := FirstPt;
for i := 0 to High(ctrlPts) div 2 do
begin
p[0] := pt;
p[1] := ctrlPts[i*2];
p := OffsetPath(p, -designer.Left, -designer.Top);
DrawDashedLine(designer.Image, p, dashes,
nil, Self.Owner.StrokeWidth/2, clRed32, esRound);
pt := ctrlPts[i*2+1];
p[0] := ctrlPts[i*2];
p[1] := pt;
p := OffsetPath(p, -designer.Left, -designer.Top);
DrawDashedLine(designer.Image, p, dashes,
nil, Self.Owner.StrokeWidth/2, clRed32, esRound);
end;
end;
end;
//------------------------------------------------------------------------------
// TSvgSSegLayer
//------------------------------------------------------------------------------
function TSvgSSegLayer.CreateBtnGroup: TButtonGroupLayer32;
var
i: integer;
begin
Result := inherited CreateBtnGroup;
//NB: THE FIRST LAYER IN THIS GROUP IS THE DESIGNER LAYER
for i := 1 to Result.ChildCount div 2 do
with TButtonDesignerLayer32(Result[i*2-1]) do
begin
Color := controlBtnColor;
Draw;
Move(Result, i*2);
end;
end;
//------------------------------------------------------------------------------
procedure TSvgSSegLayer.DrawDesigner(designer: TLayer32);
var
i,j: integer;
p: TPathD;
dashes: TArrayOfInteger;
begin
j := Ceil(Owner.StrokeWidth);
SetLength(dashes, 2);
dashes[0] := j; dashes[1] := j;
SetLength(p, 2);
with fSeg do
begin
designer.SetInnerBounds(GetCtrlBounds);
for i := 0 to High(ctrlPts) div 2 do
begin
p[0] := ctrlPts[i*2];
p[1] := ctrlPts[i*2+1];
p := OffsetPath(p, -designer.Left, -designer.Top);
DrawDashedLine(designer.Image, p, dashes,
nil, Self.Owner.StrokeWidth/2, clRed32, esRound);
end;
end;
end;
//------------------------------------------------------------------------------
procedure TSvgSSegLayer.BtnMoveCheck(const pos: TPointD);
var
dx,dy : integer;
layer : TPathSegLayer;
begin
layer := GetPrevSegLayer;
if layer is TSvgCSegLayer then
begin
dx := Round(pos.X - fSeg.FirstPt.X);
dy := Round(pos.Y - fSeg.FirstPt.Y);
if (dx <> 0) or (dy <> 0) then
begin
fSeg.Offset(dx, dy);
Offset(dx, dy);
end;
//reset Path to redraw and reposition the layer
Paths := Img32.Vector.Paths(fSeg.FlatPath);
DrawPath;